vlookup函數是什么意思 vlookup怎么用詳細步驟?

vlookup是Excel中一個函數類型，Vlookup函數是指在縱向區域查找的意思。Vlookup函數的用法是，在某一單元格中輸入【=Vlookup(查找的數據，查找的區域，返回值在查找區域的列數，匹配方式)】。

vlookup怎么用詳細步驟?

1、調出方法：

1、首先選擇輸出數據的表格位置，然后在上面的菜單欄中找到公式點擊進入，然后再左上角選擇插入公式，選擇進入，在彈出的菜單中輸入“vlookup”點擊確認。

2、還可以選擇輸出數據的表格位置，輸入“=vlookup”就好了。

2、基本用法

參數介紹：

VLOOKUP(找什么，在哪找，找到后返回其右側對應的第幾列數據，精確還是模糊查找)

注意：

需要說明的一點是，Excel中的幫助信息也有錯誤，比如在插入函數功能中VLOOKUP第四參數的說明就是錯的，大家注意不要被誤導哦

3、單條件查找

在E2單元格輸入=VLOOKUP(D2,$A$2:$B$12,2,0)

參數解釋：

=VLOOKUP(要查找的銷售員,包含銷售員和其銷售額的數據源區域,找到后返回第2列,精確查找)

第一參數：找什么(或者說按什么查找)，按銷售員查找，所以輸入D2

第二參數：在哪找，數據源區域在A:B列，所以輸入$A$2:$B$12

第三參數：找到后返回第幾列，我們要查找的是銷售額，銷售額位于B列，即第二參數中的第二列，所以輸入2

第四參數：這里要精確查找，所以輸入0

3、借助名稱框查找

選擇A2:B12區域定義為查找區域，在E2單元格輸入=VLOOKUP(D2,查找區域,2,0)

注意：

利用名稱框抓取數據區域，就不用在手工去選擇區域(名稱框適用于工作簿中所有的工作表)

4、查找返回多列數據

要求：

左側表格是數據源區域，需要在右側區域根據姓名調取對應的數據，黃色區域是需要填寫公式的區域

選中H2:K5單元格區域，輸入以下公式=VLOOKUP($G2,$A$2:$E$9,COLUMN(B1),0)后按Ctrl+Enter組合鍵

5、多條件查找(一對多查找)

首先在A列增加幫助列，利用COUNT與&組合，在A2輸入=C2&COUNTIF($C$2:C2,C2)

選擇F9:H15單元格輸入=VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0)，再按Ctrl+Enter

最后為避免出現錯誤值，要在外面加上IFERROR函數，=IFERROR(VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0),"")

6、從右到左查找(反向查找)

要求：

需要按照給出的編號查找對應的銷售員姓名，黃色區域輸入公式

數據源格式不允許改動時

在F2單元格輸入=VLOOKUP(E2,IF({1,0},$B$2:$B$12,$A$2:$A$12),2,0)

此處IF函數，重新構建了一個區域，將$B$2:$B$12放到第一列，$A$2:$A$12放到第二列，查找并返回對應數據

當IF的第一參數是{1,0}時，相當于把條件成立的和不成立的放到一起，構建為一個內存數組，

1代表條件成立的時候，0代表條件不成立的時候，{1,0}形成2列，相當于B列與A列互換位置

4、區間查詢

要求：

需要按照等級劃分規則，將成績劃分到其對應的等級中

建立幫助列

注意：必須是升序排列

此函數的最后一個參數可以隱藏(不輸入)，或者輸入1

在C2單元格輸入 =VLOOKUP(B2,$I$2:$J$5,2)，將此公式展開是這樣的： =VLOOKUP(B2,{0,"D";60,"C";80,"B";90,"A"},2)

8、通配符模糊查找

此方法只適用于有唯一一個符合條件的值，否則用SUMIF比較好

vlookup的作用：

vlookup用于查找指定值所對應的另一個值。例如：查找某件產品的價格，某個同學的某科成績等。

vlookup 函數表示：

=vlookup(要查找的值，查找區域，返回值所在列號，精確匹配或近似匹配)

參數說明：

1、要查找的值：可以引用單元格的值，例如B6;也可以直接輸入，例如“紅色T恤”。

2、查找區域：用于指定查找范圍，例如A2:D10。

3、返回值所在列號：用于指定返回值在哪列，列號開始必須從指定范圍算起，

例如指定范圍為B2:E8，則 B 列為第一列，若返回值所在列號為3，則從 D 列中返回值。

4、精確匹配或近似匹配：精確匹配用0或False表示，近似匹配用1或True表示，

為“可選”項，即可填可不填，若不填，則默認值為近似匹配。